Imports System.Collections.Generic
Imports System.ComponentModel
Imports System.Data
Imports System.Drawing
Imports System.Linq
Imports System.Text
Imports System.Threading.Tasks
Imports System.Windows.Forms
Imports System.IO
Imports ColorCode
Imports SelectPdf

Namespace SelectPdf.Samples
    Partial Public Class PdfElementsPositions
        Inherits Form

        Private Sub BtnCreatePdf_Click(sender As Object, e As EventArgs) _
            Handles BtnCreatePdf.Click
            Cursor = Cursors.WaitCursor
            Dim file As String = "Document.pdf"

            Try
                ' create a new pdf document
                Dim doc As New PdfDocument()

                ' add a new page to the document
                Dim page As PdfPage = doc.AddPage()

                ' create a new pdf font
                Dim font As PdfFont = doc.AddFont(PdfStandardFont.Helvetica)
                font.Size = 20

                ' define a rendering result object
                Dim result As PdfRenderingResult

                ' create a new text element and add it to the page
                ' Important: get the rendering result returned by Add() 
                ' into the PdfRenderingResult object
                Dim text As New PdfTextElement(0, 0, "Hello world!", font)
                result = page.Add(text)

                ' add 10 more text element, leaving 30pt between the text lines
                For i As Integer = 1 To 10
                    Dim elem As New PdfTextElement(0, _
                           result.PdfPageLastRectangle.Bottom + 30, _
                           "Text line " & i, font)
                    result = page.Add(elem)
                Next

                ' save pdf document
                doc.Save(file)

                ' close pdf document
                doc.Close()
            Catch ex As Exception
                MessageBox.Show([String].Format("Error: {0}", ex.Message), "Error", _
                                MessageBoxButtons.OK, MessageBoxIcon.[Error])
                Return
            Finally
                Cursor = Cursors.Arrow
            End Try

            ' open generated pdf
            Try
                System.Diagnostics.Process.Start(file)
            Catch
                MessageBox.Show("Could not open generated pdf document", "Error", _
                                MessageBoxButtons.OK, MessageBoxIcon.[Error])
            End Try
        End Sub

        Public Sub New()
            InitializeComponent()
            Try
                ' display highlighted sample code
                Dim code As String = Helper.ReadSourceCode("PdfElementsPositions.vb")
                WBSampleCode.DocumentText = New CodeColorizer().Colorize(code, Languages.VbDotNet)
            Catch
                WBSampleCode.DocumentText = "Sample code not available"
            End Try
        End Sub

    End Class
End Namespace
