Imports System.Collections.Generic
Imports System.ComponentModel
Imports System.Data
Imports System.Drawing
Imports System.Linq
Imports System.Text
Imports System.Threading.Tasks
Imports System.Windows.Forms
Imports System.IO
Imports ColorCode
Imports SelectPdf

Namespace SelectPdf.Samples
    Partial Public Class PdfStamps
        Inherits Form

        Private Sub BtnCreatePdf_Click(sender As Object, e As EventArgs) _
            Handles BtnCreatePdf.Click
            Cursor = Cursors.WaitCursor
            Dim file As String = "Document.pdf"

            Try
                ' create a new pdf document
                Dim doc As New PdfDocument()

                ' create a new pdf font
                Dim font As PdfFont = doc.AddFont(PdfStandardFont.Helvetica)
                font.Size = 24

                ' add a new page to the document
                Dim page As PdfPage = doc.AddPage()

                ' create a new text element and add it to the page
                Dim text As New PdfTextElement(0, 0, Helper.SomeLongText(), font)
                page.Add(text)

                ' get image path
                Dim imgFile As String = AppDomain.CurrentDomain.BaseDirectory + _
                    "/../../files/logo.png"

                ' stamp all pages - add a template containing an image to the bottom right of 
                ' the page the image should repeat on all pdf pages automatically
                Dim template As PdfTemplate = doc.AddTemplate(doc.Pages(0).ClientRectangle)
                Dim img As New PdfImageElement( _
                    doc.Pages(0).ClientRectangle.Width - 300, _
                    doc.Pages(0).ClientRectangle.Height - 150, imgFile)
                template.Add(img)

                ' save pdf document
                doc.Save(file)

                ' close pdf document
                doc.Close()
            Catch ex As Exception
                MessageBox.Show([String].Format("Error: {0}", ex.Message), "Error", _
                                MessageBoxButtons.OK, MessageBoxIcon.[Error])
                Return
            Finally
                Cursor = Cursors.Arrow
            End Try

            ' open generated pdf
            Try
                System.Diagnostics.Process.Start(file)
            Catch
                MessageBox.Show("Could not open generated pdf document", "Error", _
                                MessageBoxButtons.OK, MessageBoxIcon.[Error])
            End Try
        End Sub

        Public Sub New()
            InitializeComponent()
            Try
                ' display highlighted sample code
                Dim code As String = Helper.ReadSourceCode("PdfStamps.vb")
                WBSampleCode.DocumentText = New CodeColorizer().Colorize(code, Languages.VbDotNet)
            Catch
                WBSampleCode.DocumentText = "Sample code not available"
            End Try
        End Sub

    End Class
End Namespace
